If it's straightforward to tell which programs call with zoned parameters and which with packed, I recommend creating a second program that expects zoned parameters and have it call through to the other program with a packed version of the parameter.

If that's not possible, you'll have to change the called program to handle either packed or zoned parameters:

1. Declare the parameter as a data structure, and declare another standalone field to hold the value. Example for numeric field of 5 digits:

   D  numparmDS         DS
   D    zonedparm             1     5S 0
   D    packedparm            1     5p 0
   D  numparm           S           5p 0

2. Set the value of the standalone field this way:

   C        testn               zonedparm      10   (lo indicator)
   C        if      *in10
   C        z-add   zonedparm   numparm
   C        else
   C        z-add   packedparm  numparm
   C        endif

-- Barbara Morris IBM Toronto Lab RPG Compiler Development

---

If you do not use the parameters as I/O parameters you may also try to declare the parameters passed as CONST or passed by value since the compiler (or runtime???) will take care for the correct format, then. What I do not know at the moment is if there is a need for compiling the calling programs again.

Last but not least a question of mine. If it is really a service program (CRTSRVPGM, EPM), how do you call it from a RPG/400 program (OPM)?

---

Sorry but I don't mean a service program in that way. It's a program that any application can use to accomplish something. It's an ordinary CRTBNDRPG. A thought is to go back to RPG/400 which can handle both datatypes?

By the way, we're at V4R3!

---

Although RPG/400 allows you to supress decimal data errors for both packed and zoned values, that won't fix your problem. If you declare the parameter in the called program as packed, and pass a zoned value, the program may run without an exception, but the value used in the called program would never be the same as the value that was passed.

I wish IGNDECERR had never been allowed - it causes terrible to go unnoticed. Consider this pair of programs. P1 calls P2 with a zoned parameter. P2 is compiled with IGNDECERR(*YES). P2 assigns its parameter to 2 different fields, one set to zero and the other set to -13579. After the "assignment", the two fields still have their original values.

  ----------------------    P1   --------------------
IDS          DS
I                                        1   50ZONED
C                     Z-ADD12345     ZONED
C                     CALL 'S2'
C                     PARM           ZONED
C                     SETON                     LR
  ----------------------    P2   --------------------
C           *ENTRY    PLIST
C                     PARM           P       50
 *
C                     Z-ADDP         TEMP1   50
C                     Z-ADD-13579    TEMP2
C                     Z-ADDP         TEMP2   50
 *
C           TEMP1     DSPLY          TEMP2
C                     SETON                     LR

-- Barbara Morris IBM Toronto Lab RPG Compiler Development

---