If you're going to call a module, you must use CallB or CallP. Both of these instructions require that you hard code the name of the possible modules in your program. Even if you specify a procedure pointer in a CallB statement, you must set the procedure pointer by hard-coding the name of the procedure either in the Inz keyword for the procedure pointer or in an Eval statement in your program. As far as I know, there is no way to do what you want given that you are invoking modules.

It may sound like heresy, but why do these have to be modules? If they were standalone programs, you could set a 10-character variable with the name of a program can use old-fashioned Call. Unless you are invoking the module many times, there won't be a noticable difference in performance between a bound call and a dynamic call.

Mike Cravitz

NEWS/400 Technical Editor

---

I don't know what mean by invoking a module, but if you want to call a procedure in a module it must be in a program or service program. The procedure to call can be determined at run time. Any procedure in a service program can be called dynamically with a procedure pointer. The procedure name could be in a file or program variable.

Before calling the procedure in the service program you need to "activate" the service program. This can be done two ways. Call any procedure in the service program or use the activate it (you might just create an actsrvpgm) procedure which you bind into every service program). Or, you can activate the service program using the activate program API (This is easiest in C).

After the service program is active you can use the retrieve exports api to retrieve a pointer to the procedure you want to call dynamically.

---

I think the point you might be missing here is any program that invokes a procedure must know at bind time (before run time!) the name of that procedure unless you either use MI (as was suggested in a previous post) or you use one of the new APIs which allow you to invoke procedures in a service program without binding. Both of these run time techniques are a bit tricky. NEWS/400 has a web posting on how to invoke the APIs. However, it was written by a C programmer for C programmers. One of the things I want to do when I find the time is to figure out how to do this with RPG IV. Take care.

Mike Cravitz

NEWS/400 Technical Editor

---

Mike, here's an RPG IV procedure that uses the APIs to return a procedure pointer to a procedure in a service program. Note that the "SysPtr" type depends on an unsupported feature where a declared procedure pointer can be used to hold a system pointer. If you use this feature, I recommend that you use a similar technique (using LIKE) so that if the feature goes away and RPG defines a system-pointer type, you only have to change one place. (I wrote this procedure a while back when we first found out about this "feature" - thought I might as well share it. It would need some additional error-checking to be really useful - I leave that as an exercise for the keen programmer :-)

Barbara Morris IBM Toronto Lab RPG Compiler Development

      * File: GetProcPtr
      * Sample invocations for GetProcPtr:
      *    EVAL   ptr = GetProcPtr('MYPROC' : 'MYSRVPGM' : '*LIBL')
      *    EVAL   ptr = GetProcPtr('MYPROC' : Srvpgm : Library)
      *    EVAL   ptr = GetProcPtr(%TRIM(Procname) : SrvPgm : Lib)
      * (Note that the first parameter can't have trailing blanks)
     D GetProcPtr      PR              *   PROCPTR
     D   Procedure                  100A   VARYING CONST
     D   SrvPgm                      10A   CONST
     D   Library                     10A   CONST

      * File: GetPPtr
     H NOMAIN
      /COPY GetProcPtr

      * Define a "System-pointer" type.
     D SysPtr          S               *   PROCPTR  BASED(dummy)

      *-------------------------------------------------------------------
     P GetProcPtr      B                   EXPORT
      *-------------------------------------------------------------------
     D GetProcPtr      PI              *   PROCPTR
     D   Procedure                  100A   VARYING CONST
     D   Srvpgm                      10A   CONST
     D   Library                     10A   CONST

      *-----------------------------------------------------
      * Prototypes and templates for calling ResolveSystemPtr
      * (RSLVSP.H)
      *-----------------------------------------------------
     D RSLVSP2         PR                  EXTPROC('_RSLVSP2')
     D   Ptr                               LIKE(SysPtr)
     D   Template                          LIKE(RslvTemplt) CONST
     D RSLVSP4         PR                  EXTPROC('_RSLVSP4')
     D   Ptr                               LIKE(SysPtr)
     D   Template                          LIKE(RslvTemplt) CONST
     D   LibPtr                            LIKE(SysPtr) CONST

     D RslvTemplt      DS
     D   Gen_Mat_Id                  32A
     D     TypeSubtyp                 2A   OVERLAY(Gen_Mat_Id:1)
     D     Object                    30A   OVERLAY(Gen_Mat_Id:3)
     D   Req_Auth                     2A   INZ(AUTH_NONE)

      * See QSYSINC/MIH/MICOMMON for authority constants
     D AUTH_NONE       C                   X'0000'

      *-----------------------------------------------------
      * Prototype and templates for ActivateBoundProgram
      * (QLEAWI.H)
      *-----------------------------------------------------
     D ActBndPgm       PR                  EXTPROC('QleActBndPgm')
     D   SrvpgmPtr                         LIKE(SysPtr) CONST
     D   ActMark                     10I 0
     D   ABPInfo                           LIKE(ABP_Info)
     D   ABPInfoLen                  10I 0 CONST
     D   ErrorCode                         LIKE(ErrCode)

     D ABP_Info        DS
     D   ABP_Ret                     10I 0 INZ(%size(ABP_INFO))
     D   ABP_Avail                   10I 0
     D                                8A   INZ(*ALLX'00')
     D   ABP_ActGrp                  10I 0
     D   ABP_ActMark                 10I 0
     D                                7A   INZ(*ALLX'00')
     D   ABP_Flags                    1A
     D                                1A   INZ(*ALLX'00')

      *-----------------------------------------------------
      * Prototype and templates for ActivateBoundProgram
      * (QLEAWI.H)
      *-----------------------------------------------------
     D GetExport       PR                  EXTPROC('QleGetExp')
     D   SrvpgmMark                  10I 0
     D   ExportId                    10I 0 CONST
     D   NameLen                     10I 0 CONST
     D   ExportName                 100A   CONST
     D   ExportPtr                     *   PROCPTR CONST
     D   ExportType                  10I 0
     D   ErrorCode                         LIKE(ErrCode)

     D EX_NOT_FOUND    C                   0
     D EX_PROC         C                   1
     D EX_DATA         C                   2
     D EX_NO_ACCESS    C                   3

     D ErrCode         DS
     D   ErrProv                     10I 0 INZ(0)

      *-----------------------------------------------------
      * Local Variables
      *-----------------------------------------------------
     D LibPtr          S                   LIKE(SysPtr)
     D SrvpgmPtr       S                   LIKE(SysPtr)
     D ActMark         S             10I 0
     D ProcPtr         S               *   PROCPTR
     D ExportType      S             10I 0

      *-----------------------------------------------------
      * First, get the pointer to the service program
      *-----------------------------------------------------
     C                   IF        Library = '*LIBL'
      *   They specified *LIBL
     C                   EVAL      TypeSubtyp = x'0203'
     C                   EVAL      Object = Srvpgm
     C                   CALLP     RSLVSP2(SrvpgmPtr : RslvTemplt)

     C                   ELSE
      *   They specified the library ...
      *      Get the pointer to the library
     C                   EVAL      TypeSubtyp = x'0401'
     C                   EVAL      Object = Library
     C                   CALLP     RSLVSP2(LibPtr : RslvTemplt)
     C
      *      Get the pointer to the service program
     C                   EVAL      TypeSubtyp = x'0203'
     C                   EVAL      Object = Srvpgm
     C                   CALLP     RSLVSP4(SrvpgmPtr : RslvTemplt : LibPtr)
     C                   ENDIF

      *-----------------------------------------------------
      * Now, activate the service program
      *-----------------------------------------------------
     C                   CALLP     ActBndPgm(SrvpgmPtr : ActMark :
     C                                       ABP_Info : %size(ABP_Info) :
     C                                       ErrCode)

      *-----------------------------------------------------
      * Finally, get the procedure pointer
      * We're using nameLen+name rather than export-number
      * so we pass 0 as the export number.
      *-----------------------------------------------------
     C                   CALLP     GetExport(ActMark : 0 :
     C                                       %len(Procedure) : Procedure :
     C                                       ProcPtr : ExportType :
     C                                       ErrCode)

      *-----------------------------------------------------
      * Return the procedure pointer
      *-----------------------------------------------------
     C                   IF        ExportType = EX_PROC
     C                   RETURN    ProcPtr
     C                   ELSE
     C                   RETURN    *NULL
     C                   ENDIF

     P GetProcPtr      E

Here's my test program. I created two service programs each containing a procedure called ABC - the procedures just DSPLY the names of their service program.

      * File GetPPtrT
      /COPY GetProcPtr
     D ptr             s               *   PROCPTR
     C     *entry        plist
     C                   parm                    srvpgm           10
     C                   parm                    lib              10
     C                   eval      ptr = GetProcPtr('ABC':srvpgm:lib)
     C                   callb     ptr
     C                   seton                                        lr

---